/*
 Hard-coded version of Pond library for Processing by Designeer (http://designeer.net)
 Utilizes Traer physics library (http://www.cs.princeton.edu/%7Etraer/physics/)
 Mar. 06, 2008
*/

import traer.physics.*;

class Pond {

  ParticleSystem physics;

  Particle[][] particles;
  Spring[][] springsH;
  Spring[][] springsV;
  Particle[] anchors;
  Particle anchor;

  int width, height, step;
  float x, y;

  int gridNumX;
  int gridNumY;
  float springStrength = 5.0;
  float springDamping = 0.1;
  float physicsStep = 0.1;
  float bounce = 0.8;

  float xBoundsMin;
  float xBoundsMax;
  float yBoundsMin;
  float yBoundsMax;

  boolean guide;

  Pond(int _width, int _height, float _x, float _y, int _step){
    width = _width;
    height = _height;
    x = _x;
    y = _y;
    step = _step;
    guide = false;
    initWater();
  }

  void initWater(){
    gridNumX = int(width/step);
    gridNumY = int(height/step);
    xBoundsMin = 10.0;
    xBoundsMax = width - 10.0;
    yBoundsMin = 10.0;
    yBoundsMax = height - 10.0;

    physics = new ParticleSystem(0, 0.005);
    particles = new Particle[gridNumY][gridNumX];
    springsH = new Spring[gridNumY][gridNumX];
    springsV = new Spring[gridNumY][gridNumX];

    for (int i = 0; i < gridNumY; i++)  {
      for (int j = 0; j < gridNumX; j++)    {
        particles[i][j] = physics.makeParticle(0.1, j * step, i * step, 0.0);
        if (j > 0)      {
          Particle p1 = particles[i][j - 1];
          Particle p2 = particles[i][j];
          springsV[i][j] = physics.makeSpring(p1, p2, springStrength, springDamping, step/4);
        }
        if (i > 0)      {
          Particle p1 = particles[i - 1][j];
          Particle p2 = particles[i][j];
          springsH[i][j] = physics.makeSpring(p1, p2, springStrength, springDamping, step/4);
        }
      }
    }

    //fix border
    for(int j=0; j<gridNumX; j++){
      particles[0][j].makeFixed();
      particles[gridNumY-1][j].makeFixed();
    }
    for(int i=0; i<gridNumY; i++){
      particles[i][gridNumX-1].makeFixed();
      particles[i][0].makeFixed();
    }
  }


  void drawGuide(){
    noFill();
    stroke(255);
    for (int i = 0; i < gridNumY; i++)  {
      beginShape();
      vertex(particles[i][0].position().x(), particles[i][0].position().y());
      for (int j = 0; j < gridNumX; j++)
       vertex(particles[i][j].position().x(), particles[i][j].position().y());
      vertex(particles[i][gridNumX - 1].position().x(), particles[i][gridNumX - 1].position().y());
      endShape();
    }
    for (int j = 0; j < gridNumX; j++)  {
      beginShape();
      vertex(particles[0][j].position().x(), particles[0][j].position().y());
      for (int i = 0; i < gridNumY; i++)
       vertex(particles[i][j].position().x(), particles[i][j].position().y());
      vertex(particles[gridNumY - 1][j].position().x(), particles[gridNumY - 1][j].position().y());
      endShape();
    }
  }

  void drawWater(){
    float pn;
    noStroke();
    for(int j=0; j<gridNumX-1; j++){
      beginShape(QUAD_STRIP);
      for(int i=0; i<gridNumY; i++){
        pn = noise((i+frameCount*0.25f)*0.025f,(j+frameCount*0.1f)*0.025f)*300f;
        fill(pn, pn, pn, 100-particles[i][j+1].position().z());
        vertex(particles[i][j].position().x(), particles[i][j].position().y());
        pn = noise((i+frameCount*0.25f)*0.025f,(j+1+frameCount*0.1f)*0.025f)*300f;
        fill(pn, pn, pn, 100-particles[i][j+1].position().z());
        vertex(particles[i][j+1].position().x(), particles[i][j+1].position().y());
      }
      endShape();
    }

  }

  void render(){
    physics.advanceTime(physicsStep);
    pushMatrix();
    translate(x,y);
    if(guide) drawGuide();
    else drawWater();
    popMatrix();
  }

  void ripple(int mx, int my, int strength){
    float d = -1.0;

    for (int i = 0; i < gridNumY; i++)  {
      for (int j = 0; j < gridNumX; j++)    {
        float dTemp = distance(mx, my, particles[i][j].position().x(), particles[i][j].position().y());
        if (dTemp < d || d < 0)      {
          d = dTemp;
          anchor = particles[i][j];
        }
      }
    }
    anchor.moveTo(anchor.position().x(), anchor.position().y(), strength);
    anchor.velocity().clear();
  }


  float distance(float x1, float y1, float x2, float y2){
    float dx = x2 - x1;
    float dy = y2 - y1;
    return sqrt((dx * dx) + (dy * dy));
  }

}